Shoutbox

Tips for mIRC users


1. Easy-join alias

mIRC can store a list of aliases, which are similar to Quick Texts in Messenger Plus!. This way, you can create a short alias to easily join the Plus! chat in the future. To do so, simply enter the following command in mIRC (in any window that has an editbox at the bottom):

/alias mp server $iif(($server),-m) irc.msgplus.net:6667 -j #msgplus

After doing that, mIRC should tell you that the alias has been added successfully. Now all you have to do to join the chat is type /mp. This alias will be remembered by mIRC.

If you wish to add more automatically-joined channels to your /mp alias, just use the same command as above with your own list of comma-separated channel names at the end. For example, to make the alias join both #msgplus and #banana, use this command:

/alias mp server $iif(($server),-m) irc.msgplus.net:6667 -j #msgplus,#banana

Each time you use /alias mp, the old /mp alias is overwritten by the new one you specify. I will not elaborate about aliases here - use /help Aliases to learn more about them.



2. Automatic NickServ identification

mIRC can also automatically respond to events on IRC. This allows you to do a great many things, but one of the most common applications is automatic NickServ identification. If you don't intend to register your nickname with NickServ (the IRC nickname registration service) on our server, this tip is useless for you.

(For more information about nickname and channel registration,
type /ns help and /cs help once connected to the server.)

If you have registered your nickname and wish to use automatic NickServ identification, you can use the following remote event script:

on *:NOTICE:please choose a different nick.:?:{
  if ((*.msgplus.net !iswm $server) || ($nick != NickServ)) return
  if ($me == YOURNICK) { .msg NickServ IDENTIFY YOURPASS }
}

Note that you must replace the highlighted words - YOURNICK and YOURPASS - with the nickname you registered with NickServ and the password you chose for that nickname, respectively.

To add the above script code to mIRC, firstly press Alt+R within mIRC. This should open the mIRC Editor in the Remote section. Now all you have to do is paste the above script lines anywhere in the white editbox. Make sure you copy all the lines exactly as they are, and don't change anything except for YOURNICK and YOURPASS as explained above.

Congratulations, now your mIRC should automagically identify to NickServ for your nickname whenever you connect to the server!



3. Advanced version of automatic NickServ identification

(updated June 17th, 2006)

Here's an advanced and paranoid version of the above script:


on *:NOTICE:please choose a different nick.:?:{
  if (*.msgplus.net iswm $server) {
    if ($fulladdress != NickServ!services@msgplus.net) return
    var %list

    ; List of acceptable server IP addresses
    %list = 206.180.144.97
    if (!$istok(%list,$serverip,32)) return

    ; List of acceptable server ports
    %list = 6667 6668 7000 7001
    if (!$istok(%list,$port,32)) return

    ; List of nicknames that you want to auto-identify for
    %list = YOURNICK1 YOURNICK2 YOURNICK3 ...
    if (!$istok(%list,$me,32)) return

    .msg NickServ IDENTIFY YOURPASS
  }
}


This remote script can be added in the same manner as the simple version (it should be put instead of the simple version, and not in addition to it).

Advantages over the simple version:
A. Allows for multiple auto-identified nicknames.
B. Security: Adds a NickServ user@host check, and more importantly server IP address and port checks. This makes sure nobody does any dodgy stuff.

Disadvantage:
This version may require an update in case the server details are altered. I'll try to keep it up to date.

(BTW: If you use an IRC proxy ("bouncer"), you'll have to add its IP address and listening port to the right places in the above code for it to work right. Although, doing that will render the IP/port check pointless, unless you use your proxy to connect to trusted/known IRC servers only.)