Shoutbox

quote:

---

Originally posted by wipey
How does your window say that and not the ordinary
Artist - [Album #Trackno] Song
????
I fyou could explain that it would help an awful lot lol, that is why the plugin isn't working for you...although I might be able to make a fix

---

I am a formatting string coder!
So I have coded my own window's title based on a person called upNorth's string:

code:

---

//**************************************
// Variables
//**************************************
$puts(symb_start,'.::: ')
$puts(symb_sep,' :: ')
$puts(symb_end,' :::.')
$puts(spacer_symb,' ')
$puts(spacer_width,5)
$puts(text_artist,[%artist%])
$puts(text_title,[%title%])
$puts(text_filename,[%_filename_ext%])
$puts(text_tracknumber,[$num(%tracknumber%,2)])
$puts(text_album,[%album%])
$puts(text_disc,['Disc '%disc%])
$puts(spacer,$repeat($get(spacer_symb),$get(spacer_width)))
//**************************************
// artist
//**************************************
$puts(artist,
$if($and(%artist%,%title%),
$get(text_artist)' - ',
$if(%artist%,$get(text_artist))))
//**************************************
// title
//**************************************
$puts(title,
$if(%title%,
$get(text_title),
$get(text_filename)))
//**************************************
// tracknumber
//**************************************
$puts(tracknumber,
$if(%tracknumber%,$get(symb_start)$get(text_tracknumber))
$if($or(%album%,%disc%),
$if(%tracknumber%,$get(symb_sep)),
$if(%tracknumber%,$get(symb_end))))
//**************************************
// album
//**************************************
$puts(album,
$if(%tracknumber%,,$if(%album%,$get(symb_start)))
$if(%album%,$get(text_album))
$if(%disc%,$if(%album%,$get(symb_sep)),$if(%album%,$get(symb_end))))
//**************************************
// disc
//**************************************
$puts(disc,
$if($or(%tracknumber%,%album%),
$if(%disc%,$get(text_disc)$get(symb_end)),
$if(%disc%,$get(symb_start)$get(text_disc)$get(symb_end))))
// Output
$get(artist)
$get(title)
$get(spacer)$get(tracknumber)
$get(album)
$get(disc)

---